Formats de date | En → Fr

<aside> <img src="/icons/info-alternate_gray.svg" alt="/icons/info-alternate_gray.svg" width="40px" /> *Les formules présentées ci-dessous servent à traduire les termes anglophones des formats de date en français. Vous pouvez les utiliser lorsque vous souhaitez afficher des formats de date en français dans un espace réglé en anglais. Autrement, les termes seront traduits automatiquement.

Pour des exemples de formats de date sans traduction, visitez la page suivante : [page à venir]*

Un merci tout particulier à @paps de la communauté Discord pour son aide avec les différents exemples ♡

</aside>

Table des matières

Date simple

let(
	mois, 
	["janvier", "février", "mars", "avril", "mai", "juin", "juillet", "août", "septembre", "octobre", "novembre", "décembre"],
  
	prop("Date").formatDate("D ") + 
	mois.at(prop("Date").month()-1) + 
  prop("Date").formatDate(" YYYY")
)

Date D → F (date de début - date de fin)

Date D → F

lets(
	debut, prop("Date").dateStart(),
	fin, prop("Date").dateEnd(),
	mois, 
		["janvier", "février", "mars", "avril", "mai", "juin", "juillet", "août", "septembre", "octobre", "novembre", "décembre"],
	
	debut.formatDate("D") +
  if(
    debut.month() != fin.month(),
		 " " + mois.at(debut.month()-1) +
    if(
      debut.year() != fin.year(),
      debut.formatDate(" YYYY"), 
			""
    ), 
		""
  ) 
	+ " - " +
  fin.formatDate("D ") +
  mois.at(fin.month()-1) +
  fin.formatDate(" YYYY")
)

Jour

let(
	jours,
	["Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi", "Dimanche"],

	jours.at(prop("Date").day()-1)
)

Jour à jour (date de début - date de fin)

Jour à jour

lets(
	joursmaj,
	["Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi", "Dimanche"],
	joursmin,
	["lundi", "mardi", "mercredi", "jeudi", "vendredi", "samedi", "dimanche"],

	joursmaj.at(prop("Date").dateStart().day()-1) + " à " + joursmin.at(prop("Date").dateEnd().day()-1)
)

Jour + Date simple

lets(
	jours,
		["Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi", "Dimanche"],
	mois, 
		["janvier", "février", "mars", "avril", "mai", "juin", "juillet", "août", "septembre", "octobre", "novembre", "décembre"],

	jours.at(prop("Date").day()-1) + " " +
	prop("Date").formatDate("D ") + 
	mois.at(prop("Date").month()-1) + 
  prop("Date").formatDate(" YYYY")
)